Statistik deskriptif di Excel dan Google Sheets dihitung dengan sekitar sepuluh rumus: AVERAGE dan MEDIAN untuk pusat data, MIN, MAX, QUARTILE.INC, dan STDEV.S untuk sebarannya, dan dua rumus tambahan untuk batas outlier. Di bawah ada tabel lengkapnya dengan hasil dari data contoh, sehingga kamu bisa mencocokkan apakah rumusmu sudah benar, ditambah cara menemukan outlier dan pilihan tanpa rumus.
Data Contoh
Nilai 68 pesanan dari dataset latihan kedai kopi, ditaruh di kolom B dengan judul di B1, sehingga datanya ada di B2:B69. Untuk menyalin datanya, jalankan query nilai per pesanan dari artikel GROUP BY, lalu salin hasilnya ke spreadsheet.
Kalau Excel-mu memakai pengaturan wilayah Indonesia, ganti koma pemisah argumen dengan titik koma: =QUARTILE.INC(B2:B69,1) menjadi =QUARTILE.INC(B2:B69;1).
Tabel Rumus dan Hasilnya
| Ukuran | Rumus | Hasil dengan data contoh |
|---|---|---|
| Jumlah data | =COUNT(B2:B69) |
68 |
| Total | =SUM(B2:B69) |
2.547.000 |
| Rata-rata | =AVERAGE(B2:B69) |
37.455,88 |
| Median | =MEDIAN(B2:B69) |
31.500 |
| Modus | =MODE.SNGL(B2:B69) |
22.000 |
| Minimum | =MIN(B2:B69) |
10.000 |
| Maksimum | =MAX(B2:B69) |
106.000 |
| Rentang | =MAX(B2:B69)-MIN(B2:B69) |
96.000 |
| Kuartil 1 (Q1) | =QUARTILE.INC(B2:B69,1) |
22.000 |
| Kuartil 3 (Q3) | =QUARTILE.INC(B2:B69,3) |
49.250 |
| IQR | =QUARTILE.INC(B2:B69,3)-QUARTILE.INC(B2:B69,1) |
27.250 |
| Persentil ke-90 | =PERCENTILE.INC(B2:B69,0.9) |
64.000 |
| Simpangan baku sampel | =STDEV.S(B2:B69) |
19.660,88 |
| Simpangan baku populasi | =STDEV.P(B2:B69) |
19.515,78 |
| Varians sampel | =VAR.S(B2:B69) |
386.550.263,39 |
| Koefisien variasi | =STDEV.S(B2:B69)/AVERAGE(B2:B69) |
52,49% (format sel sebagai persen) |
Semua rumus di tabel berlaku sama di Google Sheets. Di Google Sheets, QUARTILE tanpa akhiran memberi hasil yang sama dengan QUARTILE.INC.
Catatan untuk COUNT: rumus ini hanya menghitung sel berisi angka. Kalau hasilnya lebih kecil dari jumlah baris, ada angka yang tersimpan sebagai teks. Bandingkan dengan =COUNTA(B2:B69), lalu perbaiki dengan cara di membersihkan data.
STDEV.S atau STDEV.P?
STDEV.S(sampel): data yang kamu punya adalah sebagian dari kejadian yang lebih luas. Empat bulan transaksi yang dipakai untuk menggambarkan pola penjualan termasuk di sini. Ini pilihan yang paling sering benar.STDEV.P(populasi): data yang kamu punya adalah seluruh kejadian yang ingin digambarkan, misalnya nilai ujian seluruh siswa satu kelas yang memang hanya ingin dijelaskan untuk kelas itu.
STDEV tanpa akhiran adalah versi lama yang sama dengan STDEV.S, dan masih ada untuk kompatibilitas file lama.
QUARTILE.INC atau QUARTILE.EXC?
Excel punya dua cara menghitung kuartil, dan hasilnya bisa berbeda:
| QUARTILE.INC | QUARTILE.EXC | |
|---|---|---|
| Q1 data contoh | 22.000 | 22.000 |
| Q3 data contoh | 49.250 | 49.750 |
| Sama dengan | QUARTILE lama di Excel, QUARTILE di Google Sheets, Kalkulator Statistik Deskriptif |
Beberapa software statistik |
Untuk data dengan 68 baris, selisihnya kecil (Rp500 di Q3). Yang penting adalah konsisten: kalau laporan bulan lalu memakai INC, bulan ini juga pakai INC. Kalau angka kuartilmu berbeda sedikit dengan hitungan rekan kerja, cek dulu apakah salah satunya memakai EXC.
Menemukan Outlier dengan Rumus
Aturan IQR yang umum: data dianggap outlier kalau di bawah Q1 − 1,5 × IQR atau di atas Q3 + 1,5 × IQR. Simpan batasnya di dua sel:
| Sel | Rumus | Hasil |
|---|---|---|
| E2 (batas bawah) | =QUARTILE.INC(B2:B69,1)-1.5*(QUARTILE.INC(B2:B69,3)-QUARTILE.INC(B2:B69,1)) |
−18.875 |
| E3 (batas atas) | =QUARTILE.INC(B2:B69,3)+1.5*(QUARTILE.INC(B2:B69,3)-QUARTILE.INC(B2:B69,1)) |
90.125 |
Di Excel dengan pengaturan Indonesia, 1.5 ditulis 1,5.
Lalu:
- Hitung jumlah outlier:
=COUNTIF(B2:B69,">"&E3)+COUNTIF(B2:B69,"<"&E2)menghasilkan 1. - Tandai di kolom sebelah: di C2 tulis
=IF(OR(B2>$E$3,B2<$E$2),"Outlier",""), lalu salin ke bawah. Pesanan Rp106.000 akan bertanda "Outlier". - Warnai otomatis: blok B2:B69, Home → Conditional Formatting → New Rule → Use a formula, isi
=OR(B2>$E$3,B2<$E$2), lalu pilih warna. Di Google Sheets: Format → Conditional formatting → Custom formula is.
Batas bawah bernilai negatif artinya tidak mungkin ada outlier di sisi bawah untuk data ini, karena nilai pesanan tidak pernah negatif. Itu wajar untuk data uang yang miring ke kanan.
Apa yang dilakukan setelah menemukan outlier dibahas di statistik dasar untuk data analyst: cek dulu apakah salah input, dan jangan dibuang diam-diam.
Statistik per Kelompok
Rata-rata nilai pesanan per cabang, kalau kolom A berisi nama cabang:
=AVERAGEIFS(B2:B69, A2:A69, "Dago")
Median per kelompok tidak punya rumus MEDIANIFS. Di Excel 365 dan Google Sheets, gabungkan dengan FILTER:
=MEDIAN(FILTER(B2:B69, A2:A69="Dago"))
Untuk banyak kelompok sekaligus, pivot table lebih cepat.
Tanpa Rumus: Dua Pilihan
- Analysis ToolPak di Excel (Windows): aktifkan lewat File → Options → Add-ins → Excel Add-ins → Analysis ToolPak, lalu Data → Data Analysis → Descriptive Statistics. Hasilnya tabel statis yang tidak ikut berubah kalau datanya berubah.
- Kalkulator Statistik Deskriptif: salin satu kolom dari Excel atau Google Sheets, tempel, dan semua angka di tabel di atas langsung muncul, termasuk outlier. Berguna untuk cek cepat atau kalau sedang memakai komputer yang tidak ada Excel-nya. Angka diproses di browser, tidak dikirim ke server.

Kesalahan yang Sering Terjadi
- Rentang yang tidak mencakup semua data. Data bertambah, rumus masih menunjuk B2:B69. Ubah data menjadi tabel resmi (Ctrl+T) seperti di format tabel data yang rapi, lalu pakai nama kolomnya.
- Angka tersimpan sebagai teks.
AVERAGEmelewatinya tanpa peringatan. Cek denganCOUNTdibandingCOUNTA. - Sel kosong dianggap nol.
AVERAGEmengabaikan sel kosong, tetapi tidak mengabaikan sel berisi 0. Kalau "belum ada data" ditulis 0, rata-ratanya turun. - Memakai
STDEV.Puntuk data sampel. Hasilnya sedikit lebih kecil dari seharusnya. - Mencampur
QUARTILE.INCdanQUARTILE.EXCantar laporan.
Langkah Berikutnya
- Pahami arti setiap angka di statistik dasar untuk data analyst dan mean, median, modus.
- Sajikan hasilnya sebagai grafik: membuat grafik di Excel dan Google Sheets.
- Langkah ini adalah bagian dari Roadmap Spreadsheet untuk Analisis Data. Rumus inti lainnya ada di Cheat Sheet Rumus Excel & Google Sheets.